#!/usr/bin/expect -f

#======================================================================

#                    L A D C P 2 

#                    doc: Wed Mar 10 22:23:52 2004

#                    (c) 2004 A.M. Thurnherr

#======================================================================

# HISTORY:

#  Mar 10, 2004: - created

#  Mar 12, 2004: - released

#  Mar 21, 2004: - added automatic station numbering

#		 - unified prompts

#  Mar 24, 2004: - doubled station-number-entry timeout

#  Jun 18, 2004: - BUG: station 008 bombed on octal digit

#  Feb 14, 2006: - BUG: log files were written to bin dir

#  Oct  4, 2006: - adapted to older version of expect

#  Oct 31, 2007: - BUG: wrong default on non-empty memory

#  Nov 19, 2008: - adapted to new firmware behavior (load_factory_defaults)

#  Nov 19, 2008: - added version

#----------------------------------------------------------------------

# Setup

#----------------------------------------------------------------------

log_user 0;

source $path;

print_version;

if {$argc == 0} {

	set ask 1;

	if {[file isfile .last_stn]} {

		set stn [expr [exec cat .last_stn] + 1];

		set stnstr [format $stn_format $stn];

		if {[affirm "Use station number $stnstr? (y/N) " 10]} {

			set ask 0;

		}

	}

	if {$ask == 1} {

		set stn [input_int "Station number = "];

		set stnstr [format $stn_format $stn];

	}

} else {

	set stn [lindex $argv 0];

	set stnstr [format $stn_format $stn];

}

if ![file isdirectory $raw_dir] {

	error "directory $raw_dir does not exist";

}

set cast_dir [format %s/%s $raw_dir $stnstr];

if [file isdirectory $cast_dir] {

	error "data directory $cast_dir already exists!";

}

set prev_cast_dir [format %s/$stn_format $raw_dir [expr $stn - 1]];

if {![file isdirectory $prev_cast_dir]} {

	if {![affirm "WARNING: previous-station data directory $prev_cast_dir does not exist --- are you sure the station number $stnstr is ok? (y/N) " 10]} {

		send_error "$argv0 aborted\n";

		exit 0;

	}

}

#----------------------------------------------------------------------

# Deploy LADCP

#----------------------------------------------------------------------

set_color;

send_user "Connecting to instruments...";

spawn bbabble -ms $tty0 $tty1;

wait_for_startup;

reset_two_instruments;

if {![memory_empty]} {

	if {![affirm "\nWARNING: Memory is not empty; continue anyway? (y/N) " 10]} {

		send_user "Putting instruments to sleep...";

		select_master 0; put_to_sleep;

		select_slave; put_to_sleep;

		send_user "\nDone\n";

		exit;

	}

} else {

	send_user "\n";

}

exec mkdir $cast_dir;

exec cp $master_cmd_file $cast_dir;

exec cp $slave_cmd_file $cast_dir;

exec echo $stn > .last_stn;

cd $cast_dir;

if {![file isfile $master_cmd_file]} {

	error "Failed to copy $master_cmd_file to [pwd]";

}

if {![file isfile $slave_cmd_file]} {

	error "Failed to copy $slave_cmd_file to [pwd]";

}

regsub {.*/} $argv0 {} basename;

start_logging [format %s_%s.log $basename $stnstr];

send_user "Resetting instruments to factory defaults...";

select_master 0; load_factory_defaults;

select_slave; load_factory_defaults;

send_user "\nSetting instrument clocks...";

set_computer_time;

select_master 0; set_instrument_clock;

select_slave; set_instrument_clock;

send_user "\nSetting deployment names...";

select_master; set_deployment_name [format $master_deployment_name_fmt $stn];

select_slave; set_deployment_name [format $slave_deployment_name_fmt $stn];

send_user "\nUploading command files";

select_slave 0;

upload_file $slave_cmd_file [format %s_log $slave_cmd_file] "[format $slave_deployment_name_fmt $stn].hwconfig";

resume_logging [format %s_%s.log $basename $stnstr];

select_master;

upload_file $master_cmd_file [format %s_log $master_cmd_file] "[format $master_deployment_name_fmt $stn].hwconfig";

send_user "\nDone\n";