#!/usr/bin/perl

#======================================================================

#                    L A D C P _ W 

#                    doc: Fri Dec 17 18:11:13 2010

#                    (c) 2010 A.M. Thurnherr

#======================================================================

# TODO:

#	  detection so that editing stats make sense

#	- own seabed detection (P403)

#	- make upcast-flag valid for yoyo casts

#	- make diagnostic output 3-beam field work for Earth coordinates

#	- remove water-depth from BT code, which is not really used and a bit of an outlier

#	  because mean and stddev are used instead of median/mad

#	- read assumed ADCP soundspeed from data file, instead of assuming 1500m/s

#	? use instrument tilt in sidelobe editing?

$antsSummary = 'calculate vertical velocities from LADCP & CTD time series';

# HISTORY:

#	Dec 17, 2010: - created from [mergeCTD+LADCP]

#	Dec 18, 2010: - made to work

#	Dec 19, 2010: - improved considerably

#	Dec 20, 2010: - onward

#				  - BUG: depth-binning was off by 1 bin?!

#				  - added binning correction for instrument tilt

#	Dec 21, 2010: - added -h (seafloor depth)

#	Dec 22, 2010: - BUG: had not applied soundspeed-correction to w

#				  - debugged opt_d

#	Dec 23, 2010: - continued implementation of soundspeed corrections

#	Dec 24, 2010: - added winch_w, wave_w

#				  - removed beampair velocities from code

#	Dec 25, 2010: - adapted for surface-wave correction in terms of acceleration (CTD_w_t)

#				  - removed elapsed_mismatch

#				  - removed winch_w, wave_w

#	Dec 26, 2010: - made -p output layout independent of -x to avoid Makefile problems

#	Dec 30, 2010: - cleaned up some

#				  - folded-in backscatter calculation from shear method

#				  - folded-in BT calculation from shear method

#	Dec 31, 2010: - added weighted mean w profile to output

#	Jan  2, 2010: - BUG: BT_w.mad could bomb with division by 0

#				  - BUG: division by zero if no valid data

#	Jan  5, 2010: - adapted to allow for gaps in CTD time series

#	Feb 16, 2011: - cosmetics

#	Jun 22, 2011: - cosmetics

#	Jun 23, 2011: - disabled error on large rms reflr w

#				  - added -l

#				  - removed CTD headers from output

#	Jun 26, 2011: - added -u

#				  - changed package correction from acceleration to velocity, because of

#					Stan's Antarctic data set where accelerations are zero but package effects are

#					there

#	Jul  2, 2011: - increased tilt default to 15 degrees

#	Jul  3, 2011: - replaced old package-velocity correction -x code by new beamvel correction

#				  - removed -p

#				  - replaced -d by residual (diagnostics) output

#	Jul  4, 2011: - saved a snapshot in [Jul_04_2011]

#				  - removed output of binned profile (but not calculation code, which is required for residual)

#				  - BUG: firstGoodEns or lastGoodEns could end up in a reflr_w gap when valid LADCP data begin

#						 or end with CTD in water

#				  - moved rarely used option -s to -k

#				  - added -s)kip <ens> option

#				  - had to very very slightly relax an assertion (by 1e-10 seconds...)

#	Aug  3, 2011: - added -z)ap to truncate range, based on Stan's 2009 data set (017-019 most clearly)

#				    obs that final 2 velocities are outliers; could be due to color bar, should check with

#					residuals

#	Sep 22, 2011: - removed (commented out) CTD acceleration

#				  - added basename to Parameter File Matching

#	Sep 23, 2011: - cosmetics (lots)

#				  - added -d)

#	Oct  6, 2011: - removed old commented-out code (CTD acceleration & old -x)

#				  - renamed time-series field names

#				  - added uncorrected reflr w to time-series output

#	Oct 10, 2011: - BUG: LADCP_w in .tds output had not been soundspeed corrected

#				  - removed -x

#				  - added "false-positives" editing filter

#	Oct 11, 2011: - adapted to the new parameter file, removing a few options

#	Oct 12, 2011: - added surface-layer editing

#				  - made %min/max_depth/elapsed more accurate

#	Oct 13, 2011: - fiddled

#	Oct 14, 2011: - renamed .prof fields from .N to .nsamp

#				  - added %output_basename

#				  - removed all ">" from open to allow use in pipelines

#				  - made <run-label> argument optional

#				  - replaced stdout output by $w_out

#				  - renamed _out to out_; output_basename to out_basename

#	Oct 15, 2011: - added editWOutliers()

#				  - added step to remove single-ping noise

#	Oct 16, 2011: - BUG: ensemble and bin numbers in output files were off by 1

#	Oct 17, 2011: - added default run label

#				  - added out_BR

#				  - BUG: closed STDOUT caused problems with tee in plotting scripts

#				  - added %run_label

#				  - added PostProcess.sh

#	Oct 18, 2011: - BUG: %{min,max}_ens used ensemble indices, rather than numbers

#				  - disabled false-positives editing (removes too much good data on 2011_IWISE)

#	Oct 19, 2011: - BUG: time-series output included ensembles without valid w

#				  - increased post-process sleep time to 30s

#				  - added corr, Sv and echo_amplitude as new fields to w output

#	Oct 20, 2011: - added editFarBins()

#				  - added downcast flag to time-series output

#				  - added ensemble number to LADCP-time-series output

#	Oct 21, 2011: - BUG: Sv code was not enabled for uplooker data

#	Oct 24, 2011: - added code to copy %lat/%lon from CTD data

#				  - added %ADCP_freuquency, %ADCP_blanking_distance

#				  - %LADCP_bin_length => %ADCP_bin_length

#	Oct 26, 2011: - added $first_guess_timelag

#	Oct 27, 2011: - added w12, w34, ww (pitch/roll-weighted average) to full output

#				  - removed ww because it apparently does not improve the solutions

#				  - moved editTilt() to after time-series calculation to allow

#				    time matching to work even with strict tilt limit

#				  - added correctAttitude()

#	May 22, 2012: - adapted to ANTS V5

#	Oct 15, 2012: - added $edit_data_hook

# CTD REQUIREMENTS

#	- elapsed		elapsed seconds; see note below

#	- depth

#	- ss			sound speed

#	- w				ddepth/dt

#	- temp			OPTIONAL; used for backscatter calculation (i.e. not very important)

#	- %lat/%lon		OPTIONAL

# NUMERICAL OPTIONS

#	- the first option in the list cannot be numerical!

#	- if need be, use -v 1 as a dummy option

# ELAPSED TIMES

#	- there are 2 different elapsed times used in this program:

#		1) elapsed based on firstgoodens in the LADCP time series

#		2) CTD elapsed time

#	- CTD elapsed time does not have to start with zero!

#	- do not use the Seabird elapsed field, which is only reported to

#	  3 significant digits, causing significant jitter in dt; however,

#	  at least up to 2010 Seabird simply calculates elapsed time by 

#	  assuming a 24Hz sampling rate and no record drop; therefore,

#	  it is best to calculate elapsed time as %RECNO/24

#	- the elapsed field of the output is the elapsed time from the CTD

#	  file; this is required in order to be able to compare the times

#	  from the uplooker and downlooker-derived vertical velocity

#	  profiles

#	- as a result, a profile only starts with elapsed==0 if the CTD

#	  is turned on when the LADCP is already in the water

# OUTPUT NOTES

#	- residuals are calculated with respect to down-/upcast medians in binned profiles

#	- equivalence, assuming -o 10:

#		1) 004DL.prof dc_w depth

#		2) bindata -Sdowncast:1 -Fw.median,depth -n 20 depth 10 004DL.w

# VELOCITY AMBIGUITY ERRORS

#	- quite extensive tests with DIMES US2 station 146, which has a lot of

#	  ambiguity velocity errors, reveal that -m 1 catches those errors

#	  quite nicely

#	- even when the errors are not filtered with -m 1, they do not

#	  affect the w profiles, as long as the median bin values are used

($WCALC) 	  = ($0                =~ m{^(.*)/[^/]*$});

($ANTS) 	  = (`which ANTSlib`   =~ m{^(.*)/[^/]*$});

($PERL_TOOLS) = (`which mkProfile` =~ m{^(.*)/[^/]*$});

require "$ANTS/ants.pl";

require "$ANTS/libstats.pl";

require "$WCALC/edit_data.pl";

require "$WCALC/time_series.pl";

require "$WCALC/time_lag.pl";

require "$WCALC/find_seabed.pl";

require "$WCALC/svel_corrections.pl";

require "$WCALC/acoustic_backscatter.pl";

require "$WCALC/bottom_tracking.pl";

require "$PERL_TOOLS/RDI_BB_Read.pl";

require "$PERL_TOOLS/RDI_Coords.pl";

use IO::Handle;

my($TINY) = 1e-16;

#------

# Usage

#------

@ARGS = @ARGV;														# save opts & arguments

$antsParseHeader = 0;

&antsUsage('3:4a:b:c:e:g:h:i:k:m:n:o:qs:t:uv:w:x:',1,

	'[-v)erbosity <level[1]>]',

	'[-q)uick (no single-ping denoising)]',

    '[require -4)-beam solutions]',

	'[-c)orrelation <min[70]>] [-t)ilt <max[10deg]> [-e)rr-vel <max[0.1m/s]>]',

	'[-h water <depth>]',

	'[max LADCP time-series -g)ap <length[60s]>]',

	'[-m)ax vertical <velocity[1m/s]>',

	'[-a)djust CTD depth <by[0m]>]',

	'[-i)nitial CTD time offset <guestimate> [-u)se as final]]',

	'[calculate -n) <lags,lags[10,100]>] [lag -w)indow <sz,sz[240s,20s]>]',

	'[require top-3) lags to account for <frac[0.6]> of all]',

	'[valid LADCP -b)ins <bin[2],bin[*]>',

	'[-o)utput bin <resolution[10m]>] [-k) require <min[20]> samples]',

	'[e-x)ecute <perl-expr>]',

	'<station-id> [run-label]');

&antsUsageError() if ($opt_u && !defined($opt_i));

&antsCardOpt(\$opt_s,0);											# skip # initial ensembles

$STN = &antsCardArg();												# station id

if (@ARGV) {														# run label

	$RUN = $ARGV[0];

	shift;

} else {

	$RUN = 'default';

}

#-----------------------------

# Handle Processing Parameters

#-----------------------------

require "$WCALC/defaults.pl";										# load default/option parameters

require "$processing_param_file";									# load processing parameters

eval($opt_x) if defined($opt_x);									# eval cmd-line expression to override anything

croak("$0: \$out_basename undefined\n")								# all plotting routines use this

	unless defined($out_basename);

&antsAddParams('out_basename',$out_basename);

&antsAddParams('run_label',$RUN);

$out_w 	    	= ">$out_w" 		 unless ($out_w =~ /^$|^\s*\|/);	# make sure O_CREAT is set unless it's a pipe

$out_BR 	    = ">$out_BR" 		 unless ($out_BR =~ /^$|^\s*\|/);

$out_TL 	    = ">$out_TL" 		 unless ($out_TL =~ /^$|^\s*\|/);

$out_LADCPtis  	= ">$out_LADCPtis"   unless ($out_LADCPtis =~ /^$|^\s*\|/);

$out_profile    = ">$out_profile" 	 unless ($out_profile =~ /^$|^\s*\|/);

$out_timeseries = ">$out_timeseries" unless ($out_timeseries =~ /^$|^\s*\|/);

#----------------------------------------------------------------------

# Screen Logging

#	- warning levels:

#		0 probably unimportant, e.g. nonsensical parameters that probably won't affect solution

#		1 may be somewhat important

#		2 important

#----------------------------------------------------------------------

open(LOGF,">$out_log") || croak("$out_log: $!\n")

	if defined($out_log);

LOGF->autoflush(1);

sub progress(@)

{

	printf(LOGF @_) if defined($out_log);

	printf(STDERR @_) if ($verbosity_level > 1);

}

sub info(@)

{

	printf(LOGF "\t",@_) if defined($out_log);

	print(STDERR ($verbosity_level > 1) ? "\t" : "$LADCP_file: ");

	printf(STDERR @_)  if ($verbosity_level > 0);

}

sub warning(@)

{

	my($lvl,@msg) = @_;

	if (defined($out_log)) {

		print(LOGF "\nWARNING (level $lvl): ");

		printf(LOGF @msg);

		print(LOGF "\n");

	}

	return if ($verbosity_level == 0);

	print(STDERR "\n") if ($verbosity_level > 1);

	print(STDERR "WARNING (level $lvl): ");

	printf(STDERR @msg);

	print(STDERR "\n") if ($verbosity_level > 1);

}

sub debugmsg(@)

{ printf(STDERR @_) if ($verbosity_level > 2); }

#----------------

# Read LADCP data

#----------------

progress("Reading LADCP data from <$LADCP_file>...\n");

readData($LADCP_file,\%LADCP);

progress("\t%d ensembles\n",scalar(@{$LADCP{ENSEMBLE}}));

croak("$LADCP_file: not enough LADCP bins ($LADCP{N_BINS}) for choice of -r\n")

	unless ($LADCP{N_BINS} >= $refLr_lastBin);

croak("$0: first reference-layer bin outside valid range\n")

	unless ($refLr_firstBin>=1 && $refLr_firstBin<=$LADCP{N_BINS});

croak("$0: last reference-layer bin outside valid range\n")

	unless ($refLr_lastBin>=1 && $refLr_lastBin<=$LADCP{N_BINS});

croak("$0: first reference-layer bin > last reference-layer bin\n")

	unless ($refLr_firstBin <= $refLr_lastBin);

$LADCP_lastBin = $LADCP{N_BINS}-1

	if ($LADCP_lastBin eq '*');

croak("$0: first valid LADCP bin outside valid range\n")

	unless ($LADCP_firstBin>=1 && $LADCP_firstBin<=$LADCP{N_BINS});

croak("$0: last valid LADCP bin outside valid range\n")

	unless ($LADCP_lastBin>=1 && $LADCP_lastBin<=$LADCP{N_BINS});

croak("$0: first valid LADCP bin > last valid LADCP bin\n")

	unless ($LADCP_firstBin <= $LADCP_lastBin);

warning(0,"first reference-layer bin < first valid LADCP bin\n")

	unless ($refLr_firstBin >= $LADCP_firstBin);

warning(0,"last reference-layer bin > last valid LADCP bin\n")

	unless ($refLr_lastBin <= $LADCP_lastBin);

warning(1,"if at all, bin 1 should not be used for short blank-after-transmit values\n")

	if ($LADCP{BLANKING_DISTANCE}<$LADCP{BIN_LENGTH} && $refLr_firstBin==1);

&antsAddParams('ADCP_bin_length',$LADCP{BIN_LENGTH},

			   'ADCP_frequency',$LADCP{BEAM_FREQUENCY},

			   'ADCP_blanking_distance',$LADCP{BLANKING_DISTANCE});

#------------------------------------------------------------

# Edit beam-velocity data

#	1) correlation threshold

#------------------------------------------------------------

if ($LADCP{BEAM_COORDINATES}) {

	progress("Editing beam-velocity data...\n");

	$nvv = $cte = 0;

	for ($ens=0; $ens<=$#{$LADCP{ENSEMBLE}}; $ens++) {

		correctAttitude($ens,$pitch_bias,$roll_bias,$heading_bias);

		$nvv += countValidBeamVels($ens);

		$cte += editCorr($ens,$min_correlation);

#		$pte += editTilt($ens,$max_tilt);

	}

	croak("$LADCP_file: no valid data\n") unless ($nvv > 0);

	progress("\tcorrelation threshold (-c %d counts): %d velocites removed (%d%% of total)\n",$min_correlation,$cte,round(100*$cte/$nvv));

#	progress("\tattitude threshold (-t %d deg): %d velocites removed (%d%% of total)\n",$max_tilt,$pte,round(100*$pte/$nvv));

} else {

	progress("Editing velocity data...\n");

	$nvv = $cte = 0;

	for ($ens=0; $ens<=$#{$LADCP{ENSEMBLE}}; $ens++) {

		$nvv += countValidBeamVels($ens);

		$cte += editCorr_Earthcoords($ens,$min_correlation);

#		$pte += editTilt($ens,$max_tilt);

	}

	croak("$LADCP_file: no valid data\n") unless ($nvv > 0);

	progress("\tcorrelation threshold (-c %d counts): %d velocites removed (%d%% of total)\n",$min_correlation,$cte,round(100*$cte/$nvv));

#	progress("\tattitude threshold (-t %d deg): %d velocites removed (%d%% of total)\n",$max_tilt,$pte,round(100*$pte/$nvv));

}

#-------------------------------------------------------------------

# Calculate earth velocities

#	- this is done for all bins (not just valid ones), to allow

#	  useless possibility that invalid bins are used for reflr calcs

#	- also calculate separate beam-pair velocities

#	- the UNEDITED velocities are saved for the BT calculations

#	  (W is required, U & V are only used for stats that have not

#	  been very useful so far)

#-------------------------------------------------------------------

if ($LADCP{BEAM_COORDINATES}) {

	my($dummy);

	progress("Calculating earth-coordinate velocities...\n");

	progress("\tdiscarding velocities from beam $discard_velocities_from_beam\n")

		if ($discard_velocities_from_beam);

	$nvw = 0;

	for ($ens=0; $ens<=$#{$LADCP{ENSEMBLE}}; $ens++) {

		for (my($bin)=$LADCP_firstBin-1; $bin<=$LADCP_lastBin-1; $bin++) {

			undef($LADCP{ENSEMBLE}[$ens]->{VELOCITY}[$bin][$discard_velocities_from_beam-1])

				if ($discard_velocities_from_beam);

			($LADCP{ENSEMBLE}[$ens]->{U}[$bin],

			 $LADCP{ENSEMBLE}[$ens]->{V}[$bin],

			 $LADCP{ENSEMBLE}[$ens]->{W}[$bin],

			 $LADCP{ENSEMBLE}[$ens]->{ERRVEL}[$bin]) =

				velInstrumentToEarth(\%LADCP,$ens,

					velBeamToInstrument(\%LADCP,

										@{$LADCP{ENSEMBLE}[$ens]->{VELOCITY}[$bin]}));

			if (defined($LADCP{ENSEMBLE}[$ens]->{W}[$bin])) {

				$per_bin_nsamp[$bin]++;

				$nvw++;

			}

			$LADCP{ENSEMBLE}[$ens]->{GIMBAL_PITCH} =

			 	gimbal_pitch($LADCP{ENSEMBLE}[$ens]->{PITCH},$LADCP{ENSEMBLE}[$ens]->{ROLL});

			$LADCP{ENSEMBLE}[$ens]->{U_UNEDITED}[$bin] = $LADCP{ENSEMBLE}[$ens]->{U}[$bin];

			$LADCP{ENSEMBLE}[$ens]->{V_UNEDITED}[$bin] = $LADCP{ENSEMBLE}[$ens]->{V}[$bin];

			$LADCP{ENSEMBLE}[$ens]->{W_UNEDITED}[$bin] = $LADCP{ENSEMBLE}[$ens]->{W}[$bin];

			($dummy,$LADCP{ENSEMBLE}[$ens]->{W12}[$bin],

			 $dummy,$LADCP{ENSEMBLE}[$ens]->{W34}[$bin]) =

			 	velBeamToBPEarth(\%LADCP,$ens,@{$LADCP{ENSEMBLE}[$ens]->{VELOCITY}[$bin]});

		}

	}

	progress("\t$nvw valid velocities in bins $LADCP_firstBin-$LADCP_lastBin\n");

	progress("\t3-beam solutions : $RDI_Coords::threeBeam_1 " .

								  "$RDI_Coords::threeBeam_2 " .

								  "$RDI_Coords::threeBeam_3 " .

								  "$RDI_Coords::threeBeam_4\n")

	    unless ($opt_4);

} else { # Earth Coordinates

	progress("Counting valid vertical velocities...\n");

	$nvw = 0;

	for ($ens=0; $ens<=$#{$LADCP{ENSEMBLE}}; $ens++) {

		for (my($bin)=$LADCP_firstBin-1; $bin<=$LADCP_lastBin-1; $bin++) {

			($LADCP{ENSEMBLE}[$ens]->{U}[$bin],

			 $LADCP{ENSEMBLE}[$ens]->{V}[$bin],

			 $LADCP{ENSEMBLE}[$ens]->{W}[$bin],

			 $LADCP{ENSEMBLE}[$ens]->{ERRVEL}[$bin]) = @{$LADCP{ENSEMBLE}[$ens]->{VELOCITY}[$bin]};

			if (defined($LADCP{ENSEMBLE}[$ens]->{W}[$bin])) {

				$per_bin_nsamp[$bin]++;

				$nvw++;

			}

			$LADCP{ENSEMBLE}[$ens]->{U_UNEDITED}[$bin] = $LADCP{ENSEMBLE}[$ens]->{U}[$bin];

			$LADCP{ENSEMBLE}[$ens]->{V_UNEDITED}[$bin] = $LADCP{ENSEMBLE}[$ens]->{V}[$bin];

			$LADCP{ENSEMBLE}[$ens]->{W_UNEDITED}[$bin] = $LADCP{ENSEMBLE}[$ens]->{W}[$bin];

		}

	}

	progress("\t$nvw valid velocities in bins $LADCP_firstBin-$LADCP_lastBin\n");

}

croak("$LADCP_file: insufficient valid velocities\n") unless ($nvw > 1000);

#----------------------------------------------

# STEP: Edit earth-coordinate -velocity data

#	1) error-velocity threshold

#	2) vertical-velocity outliers

#	3) truncate range by deleting farthest valid velocities (disbled by default)

#----------------------------------------------

progress("Editing earth-coordinate velocity data...\n");

$evrm = $trrm = $worm = 0;

for ($ens=0; $ens<=$#{$LADCP{ENSEMBLE}}; $ens++) {

	$evrm += editErrVel($ens,$max_allowed_errvel);

	$worm += editWOutliers($ens,$per_ens_outliers_mad_limit);

	$trrm += editTruncRange($ens,$truncate_farthest_valid_bins) if ($truncate_farthest_valid_bins > 0);

}

progress("\terror-velocity threshold (-e %.1f m/s): %d velocites removed (%d%% of total in bins $LADCP_firstBin-$LADCP_lastBin)\n",

	$max_allowed_errvel,$evrm,round(100*$evrm/$nvw));

progress("\tvertical-velocity outliers ($per_ens_outliers_mad_limit x mad): %d velocites removed (%d%% of total in bins $LADCP_firstBin-$LADCP_lastBin)\n",

	$worm,round(100*$worm/$nvw));

progress("\trange truncation (-z %d bins): %d velocites removed (%d%% of total in bins $LADCP_firstBin-$LADCP_lastBin)\n",

	$truncate_farthest_valid_bins,$trrm,round(100*$trrm/$nvw))

		if ($truncate_farthest_valid_bins > 0);

#----------------------------

# Calculate LADCP time series

#----------------------------

progress("Calculating LADCP time-series...\n");

($firstGoodEns,$lastGoodEns,$LADCP_atbottom,$LADCP_w_gap_time) =

	calcLADCPts(\%LADCP,$opt_s,$refLr_firstBin,$refLr_lastBin,$max_LADCP_reflr_vel_gap);

croak("$LADCP_file: no good ensembles\n")

	unless defined($firstGoodEns) && ($lastGoodEns-$firstGoodEns > 0);

my($cast_duration) = $LADCP{ENSEMBLE}[$lastGoodEns]->{ELAPSED} -

				     $LADCP{ENSEMBLE}[$firstGoodEns]->{ELAPSED};

croak("$0: implausibly short cast ($cast_duration seconds)\n")

	unless ($cast_duration > 600);

$LADCP{MEAN_DT} = $cast_duration / ($lastGoodEns-$firstGoodEns-1);

progress("\tStart of cast     : %s (#%5d)\n",

					$LADCP{ENSEMBLE}[$firstGoodEns]->{TIME},

					$LADCP{ENSEMBLE}[$firstGoodEns]->{NUMBER});

progress("\tBottom of cast    : %s (#%5d) @ dz=%6dm\n",

					$LADCP{ENSEMBLE}[$LADCP_atbottom]->{TIME},

					$LADCP{ENSEMBLE}[$LADCP_atbottom]->{NUMBER},

					$LADCP{ENSEMBLE}[$LADCP_atbottom]->{DEPTH});

progress("\tEnd of cast       : %s (#%5d) @ dz=%6dm\n",

					$LADCP{ENSEMBLE}[$lastGoodEns]->{TIME},

					$LADCP{ENSEMBLE}[$lastGoodEns]->{NUMBER},

					$LADCP{ENSEMBLE}[$lastGoodEns]->{DEPTH});

progress("\tCast duration     : %.1f hours (pinging for %.1f hours)\n",

					$cast_duration / 3600,

					($LADCP{ENSEMBLE}[$#{$LADCP{ENSEMBLE}}]->{UNIX_TIME} -

						$LADCP{ENSEMBLE}[0]->{UNIX_TIME}) / 3600);

progress("\tMean ping interval: %.1f seconds\n",$LADCP{MEAN_DT});

if (defined($out_LADCPtis)) {

	progress("Writing LADCP-timeseries to <$out_LADCPtis>...\n");

	@antsNewLayout = ('ens','elapsed','reflr_w','reflr_w.stddev','reflr_w.nsamp','depth');

	open(STDOUT,"$out_LADCPtis") || croak("$out_LADCPtis: $!\n");

	for (my($ens)=$firstGoodEns; $ens<=$lastGoodEns; $ens++) {

		&antsOut($LADCP{ENSEMBLE}[$ens]->{NUMBER},

				 $LADCP{ENSEMBLE}[$ens]->{ELAPSED},

				 $LADCP{ENSEMBLE}[$ens]->{REFLR_W},

				 $LADCP{ENSEMBLE}[$ens]->{REFLR_W_STDDEV},

				 $LADCP{ENSEMBLE}[$ens]->{REFLR_W_NSAMP},

				 $LADCP{ENSEMBLE}[$ens]->{DEPTH});

	}

	&antsOut('EOF'); open(STDOUT,">&2");

}

#----------------------------------------------------------------------

# More editing

#	- this requires ${first,last}GoodEns to be known